この記事では、フォルダにあるExcelファイルのVBAのソースコードから文字列を一括検索する方法についてご説明します。
【動画】フォルダにあるExcelファイルのVBAのソースコードから文字列を一括検索する実際の動き
本題に入る前に、まずは次の動画をご覧ください。
フォルダ内のExcelファイルを一つ一つ開き、VBProjectのVBComponentsコレクション内からLinesプロパティでソースコードを1行ずつ取得します。
取得したソースコードに検索する文字列が含まれるか確認し、含まれていたらそのソースコードをシートに出力しています。(H列)
なお、動画内のサンプルではソースコードだけでなく、Excelのファイル名やモジュール名、スコープやプロシージャ名などもあわせてシートに出力しています。
マクロ作成の流れ
Excelファイルの例
今回は次のExcelファイルを用意しました。
黄色いセルA2にExcelファイルが格納されている置き場のフルパスを、黄色いセルA5に検索したい文字列を入力します。
【参考】Excelファイルの格納先
入力後に実行ボタンをクリックすると、検索して見つかったソースコードをA7の行から始まる表内に出力されます。
このサンプルでは他にも、Excelのファイル名やモジュール名、スコープやプロシージャ名などもあわせてシートに出力されます。
【注意】VBComponentsコレクションを扱うにはある設定を行わないとエラーになり動作しない
VBComponentsコレクションを扱うにはある設定を行わないとエラーになり動作しません。
設定を行わないままVBComponentsコレクションを呼び出そうとすると下のようにエラーが発生して正常に動作しません。
ではその必要な設定はというと、次の画面(トラストセンター画面)で行う「VBA プロジェクト オブジェクト モデルへのアクセスを信頼する」のチェックを付ける設定です。
このチェックを付けておかないとエラーが先ほどのエラーが発生してしまうので、必ずチェックをつけましょう。
なお、チェックを付けるとセキュリティ面が弱くなってしまうデメリットがあるので、もし本マクロを使わないときはチェックを外しておきましょう。
ただし、本マクロを使い終わった後のチェックの有無設定はExcelを使用している端末の環境の仕様を最優先し、その仕様に合わせて行って下さい。
あくまでExcelの設定はお使いの環境の仕様を絶対に守るようお使いくださいね。
トラストセンター画面の開き方及び「マクロの設定」の表示方法
トラストセンター画面の開き方及び「マクロの設定」の表示方法は次の通りです。
①「ファイル」をクリックする
「ファイル」をクリックします。
②「オプション」をクリックする
「オプション」をクリックします。
③「Excelのオプション」画面でトラストセンターをクリックしトラストセンターボタンをクリックする
「Excelのオプション」画面が表示されたら、「トラストセンター」をクリックします。
するとトラストセンターに関する画面が表示されるので、その中にある「トラストセンターの設定」ボタンをクリックします。
④トラストセンター画面の開き方及び「マクロの設定」が表示される
「トラストセンター」画面が表示され、「マクロの設定」をクリックすると、「マクロの設定」に関する画面が表示されます。
手順は以上になります。
コードの例
Option Explicit
Private Sub btn_exec_Click()
Dim rowCnt As Long '値を出力する行位置
Dim thisWb As Workbook '本マクロ用のワークブック用変数
Dim ws As Worksheet 'ワークシート用変数
Dim filePath As String 'VBAオブジェクトモジュールの名称を取得したいExcelファイルの格納先
Dim buf As String 'Excelのファイル名を受け取る用の一時格納用変数
Dim fileName As String 'ファイル名
Dim wb As Workbook 'ワークブック用変数
Dim vbComp As Object 'VBProjectのVBComponentsコレクション用変数
Dim aryCnt As Long '配列用カウンタ
Dim mdlNM As String 'モジュール名
Dim obj As Object 'CodeModuleオブジェクトを格納するオブジェクト変数
Dim cnt As Long 'カウンタ
Dim procName As String 'プロシージャ名用変数
Dim scopeStr As String 'スコープ用変数
Dim kindStr As String '種類用変数
'データを出力する行位置
Const bgnRowPos As Long = 8
'プロシージャの数をカウントする用のカウンタを初期化する
rowCnt = bgnRowPos
'本マクロのブックを取得する
Set thisWb = ActiveWorkbook
'本マクロのブックのシート名を取得する
Set ws = thisWb.Worksheets("work")
'モジュールに関する各情報を出力するセルをクリアする
ws.Range("A" & bgnRowPos & ":H1000").ClearContents
If Right(ws.Range("filePath").Value, 1) <> "\" Then
'入力された「Excelファイルの置き場」のフルパスの末尾に「\」が付いていない場合
'「Excelファイルの置き場」のフルパスの末尾に「\」を付けて、フルパスを変数filePathに格納する
filePath = ws.Range("filePath").Value & "\"
Else
'入力された「Excelファイルの置き場」のフルパスの末尾に「\」が付いている場合
'「Excelファイルの置き場」のフルパスを変数filePathに格納する
filePath = ws.Range("filePath").Value
End If
'VBAオブジェクトモジュールの名称を取得したいExcelファイルを取得する
buf = Dir(filePath & "*.xlsm")
'Excelファイルの数だけ処理を繰り返すループ
Do While buf <> ""
'B列のセルにファイル名を出力する
fileName = buf
'Excelファイルを開き、そのExcelファイルの情報をwbに代入する
Set wb = Workbooks.Open(filePath & buf)
' 配列を初期化
ReDim myArray(0)
'VBProjectのVBComponentsコレクション内の各VBComponentに対して以下を繰り返すFor文
For Each vbComp In wb.VBProject.VBComponents
'動的配列の再宣言を行う(配列に格納されている値を残したまま)
ReDim Preserve myArray(aryCnt)
'取得したモジュール名を配列に格納する
myArray(aryCnt) = vbComp.Name
'カウンタを1増やす
aryCnt = aryCnt + 1
Next vbComp
For aryCnt = 0 To UBound(myArray)
'C列のセルにモジュール名を出力する
mdlNM = myArray(aryCnt)
'VBComponentsプロパティから取得したVBComponentオブジェクトのCodeModuleオブジェクトを取得する
Set obj = wb.VBProject.VBComponents(myArray(aryCnt)).CodeModule
With obj
'対象モジュールの行数分ループするfor文
For cnt = 1 To .CountOfLines
'プロシージャ名を取得してprocNameに格納する
procName = .ProcOfLine(cnt, 0)
If obj.Lines(cnt, 1) <> "" Then
'行が空白でない場合
'スコープの取得
Select Case True
Case InStr(LCase(.Lines(cnt, 1)), "public ") > 0
'プロシージャ名が含まれているソースコードに「public 」が含まれている場合
'変数scopeStrに「public」を格納する
scopeStr = "public"
Case InStr(LCase(.Lines(cnt, 1)), "private ") > 0
'プロシージャ名が含まれているソースコードに「private 」が含まれている場合
'変数scopeStrに「private」を格納する
scopeStr = "private"
Case InStr(LCase(.Lines(cnt, 1)), "friend ") > 0
'プロシージャ名が含まれているソースコードに「Friend 」が含まれている場合
'変数scopeStrに「friend」を格納する
scopeStr = "friend"
Case InStr(LCase(.Lines(cnt, 1)), "static ") > 0
'プロシージャ名が含まれているソースコードに「Static 」が含まれている場合
'変数scopeStrに「static」を格納する
scopeStr = "static"
End Select
'種類の取得
Select Case True
Case InStr(LCase(.Lines(cnt, 1)), "sub ") > 0
'プロシージャ名が含まれているソースコードに「sub 」が含まれている場合
'変数kindStrに「sub」を格納する
kindStr = "sub"
Case InStr(LCase(.Lines(cnt, 1)), "function ") > 0
'プロシージャ名が含まれているソースコードに「function 」が含まれている場合
'変数kindStrに「function」を格納する
kindStr = "function"
Case InStr(LCase(.Lines(cnt, 1)), "property let ") > 0
'プロシージャ名が含まれているソースコードに「property let 」が含まれている場合
'変数kindStrに「Property Let」を格納する
kindStr = "Property Let"
Case InStr(LCase(.Lines(cnt, 1)), "property set ") > 0
'プロシージャ名が含まれているソースコードに「property set 」が含まれている場合
'変数kindStrに「property set」を格納する
kindStr = "Property Set"
Case InStr(LCase(.Lines(cnt, 1)), "property get ") > 0
'プロシージャ名が含まれているソースコードに「property get 」が含まれている場合
'変数kindStrに「Property Get」を格納する
kindStr = "Property Get"
End Select
If InStr(LCase(obj.Lines(cnt, 1)), LCase(ws.Range("findStr").Value)) > 0 Then
'A列のセルに「項番」を出力する
ws.Range("A" & rowCnt).Value = rowCnt - bgnRowPos + 1
If fileName <> "" Then
'fileNMがブランクではない場合
'B列のセルにファイル名を出力する
ws.Range("B" & rowCnt).Value = fileName
'fileNMをブランクにする
fileName = ""
End If
If mdlNM <> "" Then
'mdlNMがブランクではない場合
'C列のセルにモジュール名を出力する
ws.Range("C" & rowCnt).Value = mdlNM
'mdlNMをブランクにする
mdlNM = ""
End If
If scopeStr <> "" Then
'scopeStrに値が存在する場合
If procName <> "" Then
'procNameがブランクではない場合
'D列のセルに「スコープ」を出力する
ws.Range("D" & rowCnt).Value = scopeStr
End If
End If
If kindStr <> "" Then
'kindStrに値が存在する場合
If procName <> "" Then
'procNameがブランクではない場合
'E列のセルに「種類」を出力する
ws.Range("E" & rowCnt).Value = kindStr
End If
End If
'F列のセルにプロシージャ名を出力する
ws.Range("F" & rowCnt).Value = procName
'「コード内から検索する文字列」を含んだソースコードが何行目にあるのか出力する
ws.Range("G" & rowCnt).Value = cnt
'「コード内から検索する文字列」を含んだソースコードを出力する
ws.Range("H" & rowCnt).Value = .Lines(cnt, 1)
'rowCntの値を1つ増やす
rowCnt = rowCnt + 1
End If
End If
DoEvents
Next cnt
End With
Next
Set obj = Nothing
'開いたExcelファイルを閉じる
Workbooks(buf).Close SaveChanges:=False
'次のファイルを取得する
buf = Dir()
'配列を初期化する
Erase myArray
'カウンタを初期化する
aryCnt = 0
Loop
If rowCnt = bgnRowPos Then
'モジュールが1件もない場合(rowCntの初期値がbgnRowPosの値なので)
MsgBox "検索した文字列が見つかりませんでした"
End If
'後処理
Set obj = Nothing
Set wb = Nothing
End Sub
注目すべきコード①
最初に見て頂きたいのは53行目から56行目です。
'VBAオブジェクトモジュールの名称を取得したいExcelファイルを取得する
buf = Dir(filePath & "*.xlsm")
'Excelファイルの数だけ処理を繰り返すループ
Do While buf <> ""
コードの説明
以上のコードは、今回のサンプルのA2の黄色いセルに入力されたExcelファイルの置き場にあるExcelファイルを取得し、Excelファイルの数だけ処理を繰り返すコードです。
Dir関数の引数にExcelファイルの置き場をフルパスで指定して実行することでExcelファイルを取得することができます。
取得したら変数bufに格納されます。
ちなみに、Excelファイルの置き場の全てを取得するには、269行目のDir関数を繰り返し実行することで取得することができます。
'次のファイルを取得する
buf = Dir()
全てのExcelファイルを取得し終わったら、次のDir関数の戻り値がブランクになるのでDo文のループが終了します。
全てExcelファイル名を取得した後にDir関数を実行した直後の状態
変数bufがブランクなのでDoループから抜ける
注目すべきコード②
次に見て頂きたいのは62行目です。
'Excelファイルを開き、そのExcelファイルの情報をwbに代入する
Set wb = Workbooks.Open(filePath & buf)
コードの説明
以上のコードは、Openメソッドの引数にExcelファイルをフルパスで指定して実行し、そのExcelファイルの情報をwbに代入している処理のコードです。
Openメソッドを実行することでExcelファイルが開かれ、マクロがそのExcelファイルのマクロのコードを参照することができます。
つまり、Excelファイルにどんなモジュールがあるのかや、そのモジュール内にどんなプロシージャがあるのかを特定することができるようになります。
注目すべきコード③
次に見て頂きたいのは65行目から79行目です。
' 配列を初期化
ReDim myArray(0)
'VBProjectのVBComponentsコレクション内の各VBComponentに対して以下を繰り返すFor文
For Each vbcomp In wb.VBProject.VBComponents
'動的配列の再宣言を行う(配列に格納されている値を残したまま)
ReDim Preserve myArray(aryCnt)
'取得したモジュール名を配列に格納する
myArray(aryCnt) = vbcomp.Name
'カウンタを1増やす
aryCnt = aryCnt + 1
Next vbComp
コードの説明
以上のコードは、モジュール名を取得してそのモジュール名を配列に格納する処理のコードです。
コードの詳細
65行目のコードでは、配列myArrayを要素数0で初期化しています。
68行目では、VBProjectのVBComponentsコレクション内の各VBComponentに対して処理を繰り返すFor文を用意し、vbcompにはモジュールが格納されます。
71行目では動的配列の再宣言を行い、74行目ではnameプロパティからモジュールの名称を取得して配列myArrayに格納します。
For文内の処理が全て完了すると、Excelのモジュール名が全て取得されます。
注目すべきコード④
次に見て頂きたいのは87行目です。
'VBComponentsプロパティから取得したVBComponentオブジェクトのCodeModuleオブジェクトを取得する
Set obj = wb.VBProject.VBComponents(myArray(aryCnt)).CodeModule
コードの説明
以上のコードは、VBComponentsプロパティから取得したVBComponentオブジェクトのCodeModuleオブジェクトを取得する処理のコードです。
CodeModuleオブジェクトを取得して変数objに格納していますが、このオブジェクトによりVBAのソースコードを参照することができます。
ソースコード内にあるプロシージャを取得するのにこのオブジェクトが必要になります。
注目すべきコード⑤
次に見て頂きたいのは89行目から95行目です。
With obj
'対象モジュールの行数分ループするfor文
For cnt = 1 To .CountOfLines
'プロシージャ名を取得してprocNameに格納する
procName = .ProcOfLine(cnt, 0)
コードの説明
以上のコードは、VBAのソースコードの行数分ループさせるループ処理のコードと、プロシージャ名を取得するコードです。
CountOfLinesプロパティはVBAのソースコードの行数のことです。
例えば、VBAのソースコードが10行の場合、CountOfLinesプロパティは10の値を返します。
また、ProcOfLineメソッドはプロシージャ名を取得するメソッドです。
取得したら変数procNameに格納します。
このprocNameの値はシートにプロシージャ名を出力するのに使います。
注目すべきコード⑥
次に見て頂きたいのは97行目です。
If obj.Lines(cnt, 1) <> "" Then
'行が空白でない場合
コードの説明
以上のコードは、コードの行が空白でないか判定するために必要な条件文のIFです。
コードの行からプロシージャ名を取得するので、空白行は対象外にします。
注目すべきコード⑦
次に見て頂きたいのは103行目から133行目です。
'スコープの取得
Select Case True
Case InStr(LCase(.Lines(cnt, 1)), "public ") > 0
'プロシージャ名が含まれているソースコードに「public 」が含まれている場合
'変数scopeStrに「public」を格納する
scopeStr = "public"
Case InStr(LCase(.Lines(cnt, 1)), "private ") > 0
'プロシージャ名が含まれているソースコードに「private 」が含まれている場合
'変数scopeStrに「private」を格納する
scopeStr = "private"
Case InStr(LCase(.Lines(cnt, 1)), "friend ") > 0
'プロシージャ名が含まれているソースコードに「Friend 」が含まれている場合
'変数scopeStrに「friend」を格納する
scopeStr = "friend"
Case InStr(LCase(.Lines(cnt, 1)), "static ") > 0
'プロシージャ名が含まれているソースコードに「Static 」が含まれている場合
'変数scopeStrに「static」を格納する
scopeStr = "static"
End Select
コードの説明
以上のコードは、スコープを取得するコードの処理です。
プロシージャに使われているスコープ(public、private、friend、static)がどれなのかを判定します。
スコープがどれなのかは、行に対してInStr関数を使って判定します。
コードの詳細
105行目のコードでは、InStrの引数に「public 」を指定し、戻り値が0以上の場合はスコープがpublicなので、110行目で変数scopeStrに「public」を格納しています。
ただしpublicの文字列が「Public」のように大文字小文字が混ざっているかもしれないので、LCase関数を使って文字全てを小文字に変換してからInstr関数を実行しています。
なお、変数scopeStrの値は、シートの表のD列に出力するのに使います。
112行目のコードでは、InStrの引数に「private 」を指定し、戻り値が0以上の場合はスコープがprivateなので、117行目で変数scopeStrに「private」を格納しています。
119行目のコードでは、InStrの引数に「friend 」を指定し、戻り値が0以上の場合はスコープがfriendなので、124行目で変数scopeStrに「friend」を格納しています。
126行目のコードでは、InStrの引数に「static 」を指定し、戻り値が0以上の場合はスコープがstaticなので、131行目で変数scopeStrに「static」を格納しています。
注目すべきコード⑧
次に見て頂きたいのは137行目から174行目です。
'種類の取得
Select Case True
Case InStr(LCase(.Lines(cnt, 1)), "sub ") > 0
'プロシージャ名が含まれているソースコードに「sub 」が含まれている場合
'変数kindStrに「sub」を格納する
kindStr = "sub"
Case InStr(LCase(.Lines(cnt, 1)), "function ") > 0
'プロシージャ名が含まれているソースコードに「function 」が含まれている場合
'変数kindStrに「function」を格納する
kindStr = "function"
Case InStr(LCase(.Lines(cnt, 1)), "property let ") > 0
'プロシージャ名が含まれているソースコードに「property let 」が含まれている場合
'変数kindStrに「Property Let」を格納する
kindStr = "Property Let"
Case InStr(LCase(.Lines(cnt, 1)), "property set ") > 0
'プロシージャ名が含まれているソースコードに「property set 」が含まれている場合
'変数kindStrに「property set」を格納する
kindStr = "Property Set"
Case InStr(LCase(.Lines(cnt, 1)), "property get ") > 0
'プロシージャ名が含まれているソースコードに「property get 」が含まれている場合
'変数kindStrに「Property Get」を格納する
kindStr = "Property Get"
End Select
コードの説明
以上のコードは、プロシージャまたはpropertyの種類を取得するコードの処理です。
プロシージャに使われているプロシージャまたはpropertyの種類(sub、function、property let、Property Set、Property Get)がどれかなのかを判定します。
スコープがどれなのかは、行に対してInStr関数を使って判定します。
コードの詳細
139行目のコードでは、InStrの引数に「sub 」を指定し、戻り値が0以上の場合はプロシージャの種類がsubなので、144行目で変数scopeStrに「sub」を格納しています。
ただしsubの文字列が「Sub」のように大文字小文字が混ざっているかもしれないので、LCase関数を使って文字全てを小文字に変換してからInstr関数を実行しています。
なお、変数kingStrの値は、シートの表のE列に出力するのに使います。
146行目のコードでは、InStrの引数に「function 」を指定し、戻り値が0以上の場合はプロシージャの種類がfunctionなので、151行目で変数scopeStrに「function」を格納しています。
153行目のコードでは、InStrの引数に「property let 」を指定し、戻り値が0以上の場合はpropertyの種類がproperty letなので、158行目で変数scopeStrに「property let」を格納しています。
160行目のコードでは、InStrの引数に「property set 」を指定し、戻り値が0以上の場合はpropertyの種類がproperty setなので、165行目で変数scopeStrに「property set」を格納しています。
167行目のコードでは、InStrの引数に「property get 」を指定し、戻り値が0以上の場合はpropertyの種類がproperty getなので、172行目で変数scopeStrに「property get」を格納しています。
注目すべきコード⑨
次に見て頂きたいのは176行目です。
If InStr(LCase(obj.Lines(cnt, 1)), LCase(ws.Range("findStr").Value)) > 0 Then
コードの説明
以上のコードは、ソースコードに検索する文字列が含まれているかを判定しているコードです。
もし検索する文字列が含まれている場合は、「注目すべきコード⑩」の処理に進みます。
ソースコードに検索する文字列が含まれているかを判定するにはInStr関数を使い、0以上の場合は含まれているので0以上かどうかをIf文で判定しています。
注目すべきコード⑩
次に見て頂きたいのは179行目です。
'A列のセルに「項番」を出力する
ws.Range("A" & rowCnt).Value = rowCnt - bgnRowPos + 1
コードの説明
以上のコードは、A列のセルに「項番」を出力するコードです。
注目すべきコード⑪
次に見て頂きたいのは181行目から191行目です。
If fileName <> "" Then
'fileNMがブランクではない場合
'B列のセルにファイル名を出力する
ws.Range("B" & rowCnt).Value = fileName
'fileNMをブランクにする
fileName = ""
End If
コードの説明
以上のコードは、B列のセルにファイル名を出力するコードです。
fileNMがブランクでない場合はB列のセルにファイル名を出力し、ブランクの場合は特に何もしません。
注目すべきコード⑫
次に見て頂きたいのは193行目から203行目です。
If mdlNM <> "" Then
'mdlNMがブランクではない場合
'C列のセルにモジュール名を出力する
ws.Range("C" & rowCnt).Value = mdlNM
'mdlNMをブランクにする
mdlNM = ""
End If
コードの説明
以上のコードは、C列のセルにモジュール名を出力するコードです。
mdlNMがブランクでない場合はC列のセルにモジュール名を出力し、ブランクの場合は特に何もしません。
注目すべきコード⑬
次に見て頂きたいのは205行目から218行目です。
If scopeStr <> "" Then
'scopeStrに値が存在する場合
If procName <> "" Then
'procNameがブランクではない場合
'D列のセルに「スコープ」を出力する
ws.Range("D" & rowCnt).Value = scopeStr
End If
End If
コードの説明
以上のコードは、D列のセルにモジュール名を出力するコードです。
scopeStrがブランクでない場合はD列のセルに「スコープ」を出力し、ブランクの場合は特に何もしません。
注目すべきコード⑭
次に見て頂きたいのは220行目から233行目です。
If kindStr <> "" Then
'kindStrに値が存在する場合
If procName <> "" Then
'procNameがブランクではない場合
'E列のセルに「種類」を出力する
ws.Range("E" & rowCnt).Value = kindStr
End If
End If
以上のコードは、E列のセルに「種類」を出力するコードです。
kindStrがブランクでない場合はE列のセルに「種類」を出力し、ブランクの場合は特に何もしません。
注目すべきコード⑮
次に見て頂きたいのは236行目から242行目です。
'F列のセルにプロシージャ名を出力する
ws.Range("F" & rowCnt).Value = procName
'「コード内から検索する文字列」を含んだソースコードが何行目にあるのか出力する
ws.Range("G" & rowCnt).Value = cnt
'「コード内から検索する文字列」を含んだソースコードを出力する
ws.Range("H" & rowCnt).Value = .Lines(cnt, 1)
コードの説明
以上のコードは、プロシージャ名、「コード内から検索する文字列」を含んだソースコードが何行目にあるのか、「コード内から検索する文字列」を含んだソースコードをセルに出力する処理のコードです。
コードの詳細
236行目のコードでは、F列のセルにプロシージャ名を出力します。
239行目のコードでは、G列のセルに「コード内から検索する文字列」を含んだソースコードが何行目にあるのか出力します。
242行目のコードでは、H列のセルに「コード内から検索する文字列」を含んだソースコードを出力します。
動作確認
マクロ実行前
今回は以下のExcelファイルを用意しました。
マクロを実行すると、パス「C:¥work¥10_勉強¥10_VBA関連¥0223¥file」配下にあるExcelファイルのVBAのソースコードから、「debug」の文字列を検索して特定して表に各情報を出力します。
なお、パス「C:¥work¥10_勉強¥10_VBA関連¥0223¥file」配下にあるExcelファイルは下の画像の通りです。
0223_1.xlsmの「debug」の文字列の在り処
cls_0223_1のモジュールの77行目に「debug」の文字列が存在しています。
ThisWorkbookモジュールの9行目に「debug」の文字列が存在しています。
0223_2.xlsmの「debug」の文字列の在り処
0223_2.xlsmには「debug」の文字列が存在しませんでした。
0223_3.xlsmの「debug」の文字列の在り処
0223_3.xlsmには「debug」の文字列が存在しませんでした。
0223_4.xlsmの「debug」の文字列の在り処
mdl_0223_4のモジュールの5行目に「debug」の文字列が存在しています。
mdl_0223_4のモジュールの10行目に「debug」の文字列が存在しています。
mdl_0223_4のモジュールの11行目に「debug」の文字列が存在しています。
マクロ実行後
マクロを実行すると、表にソースコードや、Excelのファイル名やモジュール名、スコープやプロシージャ名などが出力されました。
最後に
この記事では、フォルダにあるExcelファイルのVBAのソースコードから文字列を一括検索する方法についてご説明しました。
VBAのソースコードから何か文字列を検索したい場合は、いちいちExcelファイルを開いてVBE画面を表示させてないといけません。
その手間が面倒だと感じている場合は本記事を参考にしてみてくださいね。
また、不要なコードやコメントを削除したい時、どこにあったかうろ覚え…といったときにサクッと探したい時にも使えるかと思います。
プログラミングのスキルを習得するなら
プログラミングのスキルを習得したい、今のスキルをもっと高めたい、そう考えているなら「プログラミングスクール」がおすすめです。
プログラミングのスキルの基礎を身につけるなら「TechAcademy」で1週間の無料体験があるので、これで「プログラミングの基礎」を学ぶのにおすすめですよ。
