【ExcelVBA】フォルダ内のExcelにあるモジュール名とプロシージャ名を全て取得するには

この記事では、フォルダ内のExcelにあるモジュール名とプロシージャ名を全て取得する方法についてご説明します。

【動画】フォルダ内のExcelにあるモジュール名とプロシージャ名を全て取得する実際の動き

本題に入る前に、まずは次の動画をご覧ください。


フォルダ内のExcelファイルを一つ一つ開き、VBProjectのVBComponentsコレクション内からモジュール名を、CodeModuleプロパティからプロシージャ名を取得しています。

モジュール名とプロシージャ名を取得したら、それぞれシートに出力しています。

マクロ作成の流れ

STEP.1
フォルダ内のExcelファイルを開く
フォルダ内のExcelファイルを開きます。
STEP.2
VBComponentsコレクションから、モジュール名を取得する
VBComponentsコレクションから、モジュール名を取得します。
STEP.3
CodeModuleプロパティからプロシージャ名を取得する
CodeModuleプロパティからプロシージャ名を取得します。
STEP.4
Excelのファイルの数だけSTEP.1からSTEP.3まで繰り返す
Excelのファイルの数だけSTEP.1からSTEP.3まで繰り返します。

Excelファイルの例

今回は次のExcelファイルを用意しました。

黄色いセルA2に、Excelファイルが格納されている置き場のフルパスを入力します。

【参考】Excelファイルの格納先

入力後に実行ボタンをクリックするとA5からF60までのセルの表内にExcelファイルのモジュール名やプロシージャ名が出力されます。

【注意】VBComponentsコレクションを扱うにはある設定を行わないとエラーになり動作しない

VBComponentsコレクションを扱うにはある設定を行わないとエラーになり動作しません。

設定を行わないままVBComponentsコレクションを呼び出そうとすると下のようにエラーが発生して正常に動作しません。

ではその必要な設定はというと、次の画面(トラストセンター画面)で行う「VBA プロジェクト オブジェクト モデルへのアクセスを信頼する」のチェックを付ける設定です。

このチェックを付けておかないとエラーが先ほどのエラーが発生してしまうので、必ずチェックをつけましょう。

なお、チェックを付けるとセキュリティ面が弱くなってしまうデメリットがあるので、もし本マクロを使わないときはチェックを外しておきましょう。

補足

ただし、本マクロを使い終わった後のチェックの有無設定はExcelを使用している端末の環境の仕様を最優先し、その仕様に合わせて行って下さい。
あくまでExcelの設定はお使いの環境の仕様を絶対に守るようお使いくださいね。

トラストセンター画面の開き方及び「マクロの設定」の表示方法

トラストセンター画面の開き方及び「マクロの設定」の表示方法は次の通りです。

①「ファイル」をクリックする

「ファイル」をクリックします。

②「オプション」をクリックする

「オプション」をクリックします。

③「Excelのオプション」画面でトラストセンターをクリックしトラストセンターボタンをクリックする

「Excelのオプション」画面が表示されたら、「トラストセンター」をクリックします。

するとトラストセンターに関する画面が表示されるので、その中にある「トラストセンターの設定」ボタンをクリックします。

④トラストセンター画面の開き方及び「マクロの設定」が表示される

「トラストセンター」画面が表示され、「マクロの設定」をクリックすると、「マクロの設定」に関する画面が表示されます。

手順は以上になります。

コードの例

Option Explicit

Private Sub btn_exec_Click()

    Dim cnt             As Long         'カウンタ
    Dim rowCnt          As Long          '値を出力する行位置
    Dim mdlfstNum       As Integer      'モジュールが最初に見つかった場合に値を格納する変数
    Dim procName        As String       'プロシージャ名用変数
    Dim ws              As Worksheet    'ワークシート用変数
    Dim filePath        As String       'VBAオブジェクトモジュールの名称を取得したいExcelファイルの格納先
    Dim buf             As String       'Excelのファイル名を受け取る用の一時格納用変数
    Dim wb              As Workbook     'ワークブック用変数
    Dim vbComp          As Object       'VBProjectのVBComponentsコレクション用変数
    Dim aryCnt          As Long         '配列用カウンタ
    Dim obj             As Object       'CodeModuleオブジェクトを格納するオブジェクト変数
    Dim scopeStr        As String       'スコープ用変数
    Dim kindStr         As String       '種類用変数
    Dim procNum         As Long         'プロシージャの数用カウンタ
        
    'データを出力する行位置
    Const bgnRowPos As Long = 5
    
    'カウンタを初期化する
    cnt = 0
    
    'プロシージャの数をカウントする用のカウンタを初期化する
    rowCnt = bgnRowPos
    
    '変数mdlfstNumを0で初期化する
    mdlfstNum = 0
        
    'プロシージャ名用変数にはじめは関数名には存在しない適当な文字列を入力しておく(ブランク状態にはしない)
    procName = "dummyStr"
    
    '本マクロのブックのシート名を取得する
    Set ws = ThisWorkbook.Worksheets("work")
    
    'モジュールに関する各情報を出力するセルをクリアする
    ws.Range("A" & bgnRowPos & ":F100").ClearContents

    If Right(ws.Range("filePath").Value, 1) <> "\" Then
    
        '入力された「Excelファイルの置き場」のフルパスの末尾に「\」が付いていない場合
        
        '「Excelファイルの置き場」のフルパスの末尾に「\」を付けて、フルパスを変数filePathに格納する
        filePath = ws.Range("filePath").Value & "\"
        
    Else
    
        '入力された「Excelファイルの置き場」のフルパスの末尾に「\」が付いている場合
    
        '「Excelファイルの置き場」のフルパスを変数filePathに格納する
        filePath = ws.Range("filePath").Value
        
    End If
    
    'VBAオブジェクトモジュールの名称を取得したいExcelファイルを取得する
    buf = Dir(filePath & "*.xlsm")

    'Excelファイルの数だけ処理を繰り返すループ
    Do While buf <> ""
        
        'B列のセルにファイル名を出力する
        ws.Range("B" & rowCnt).Value = buf
    
        'Excelファイルを開き、そのExcelファイルの情報をwbに代入する
        Set wb = Workbooks.Open(filePath & buf)
        
        ' 配列を初期化
        ReDim myArray(0)
        
        'VBProjectのVBComponentsコレクション内の各VBComponentに対して以下を繰り返すFor文
        For Each vbComp In wb.VBProject.VBComponents
        
            '動的配列の再宣言を行う(配列に格納されている値を残したまま)
            ReDim Preserve myArray(aryCnt)
            
            '取得したモジュール名を配列に格納する
            myArray(aryCnt) = vbComp.Name
            
            'カウンタを1増やす
            aryCnt = aryCnt + 1
            
        Next vbComp
        
        For aryCnt = 0 To UBound(myArray)
            
            'モジュール数をカウントする変数を0で初期化する
            mdlfstNum = 0
        
            'C列のセルにモジュール名を出力する
            ws.Range("C" & rowCnt).Value = myArray(aryCnt)
            
            'A列のセルに「項番」を出力する
            ws.Range("A" & rowCnt).Value = rowCnt - bgnRowPos + 1
        
            'VBComponentsプロパティから取得したVBComponentオブジェクトのCodeModuleオブジェクトを取得する
            Set obj = wb.VBProject.VBComponents(myArray(aryCnt)).CodeModule
            
            With obj

                '対象モジュールの行数分ループするfor文
                For cnt = 1 To .CountOfLines

                    'プロシージャ名を取得してprocNameに格納する
                    procName = .ProcOfLine(cnt, 0)

                    If .Lines(cnt, 1) <> "" Then
                    
                        '行が空白でない場合
                        
                        'スコープの取得
                            
                        Select Case True
                                                
                            Case InStr(LCase(.Lines(cnt, 1)), "public ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「public 」が含まれている場合
                                
                                '変数scopeStrに「public」を格納する
                                scopeStr = "public"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "private ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「private 」が含まれている場合
                                
                                '変数scopeStrに「private」を格納する
                                scopeStr = "private"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "friend ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「Friend 」が含まれている場合
                                
                                '変数scopeStrに「friend」を格納する
                                scopeStr = "Friend"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "static ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「Static 」が含まれている場合
                                
                                '変数scopeStrに「static」を格納する
                                scopeStr = "static"
                                                                
                        End Select

                        '種類の取得
                        
                        Select Case True
                        
                            Case InStr(LCase(.Lines(cnt, 1)), "sub ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「sub 」が含まれている場合
                                
                                '変数kindStrに「sub」を格納する
                                kindStr = "sub"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "function ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「function 」が含まれている場合
                                
                                '変数kindStrに「function」を格納する
                                kindStr = "function"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "property let ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「property let 」が含まれている場合
                                
                                '変数kindStrに「Property Let」を格納する
                                kindStr = "Property Let"
                                                                
                            Case InStr(LCase(.Lines(cnt, 1)), "property set ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「property set 」が含まれている場合
                                
                                '変数kindStrに「property set」を格納する
                                kindStr = "Property Set"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "property get ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「property get 」が含まれている場合
                                
                                '変数kindStrに「Property Get」を格納する
                                kindStr = "Property Get"
                                
                        End Select
                                                
                        If scopeStr <> "" Then
                        
                            'scopeStrに値が存在する場合
                        
                            'D列のセルに「スコープ」を出力する
                            ws.Range("D" & rowCnt).Value = scopeStr
                        
                            'scopeStrに空白を設定する
                            scopeStr = ""
                        
                        End If
                        
                        If kindStr <> "" Then
                        
                            'kindStrに値が存在する場合
                        
                            'E列のセルに「種類」を出力する
                            ws.Range("E" & rowCnt).Value = kindStr
                            
                            'F列のセルにプロシージャ名を出力する
                            ws.Range("F" & rowCnt).Value = procName
                            
                            'A列のセルに「項番」を出力する
                            ws.Range("A" & rowCnt).Value = rowCnt - bgnRowPos + 1
                                                        
                            'kindStrを空白に設定する
                            kindStr = ""
                            
                            'procNameを空白に設定する
                            procName = ""
                            
                            'rowCntの値を1つ増やす
                            rowCnt = rowCnt + 1
                            
                            'procNumの値を1つ増やす
                            procNum = procNum + 1
                        
                        End If
                        
                    End If

                    DoEvents

                Next cnt

            End With

            If procNum = 0 Then

                'プロシージャが無い場合

                'rowCntの値を1つ増やす
                rowCnt = rowCnt + 1
                
            End If

            'procNumを0を設定する(procNumの値を初期化する)
            procNum = 0
        
        Next

        Set obj = Nothing

        '開いたExcelファイルを閉じる
        Workbooks(buf).Close SaveChanges:=False

        '次のファイルを取得する
        buf = Dir()
        
        '配列を初期化する
        Erase myArray
        
        'カウンタを初期化する
        aryCnt = 0
                
    Loop
    
    '後処理
    Set obj = Nothing
    Set wb = Nothing
        
End Sub

注目すべきコード①

最初に見て頂きたいのは58行目から61行目です。

    'VBAオブジェクトモジュールの名称を取得したいExcelファイルを取得する
    buf = Dir(filePath & "*.xlsm")

    'Excelファイルの数だけ処理を繰り返すループ
    Do While buf <> ""

コードの説明

以上のコードは、今回のサンプルのA2の黄色いセルに入力されたExcelファイルの置き場にあるExcelファイルを取得し、Excelファイルの数だけ処理を繰り返すコードです。

Dir関数の引数にExcelファイルの置き場をフルパスで指定して実行することでExcelファイルを取得することができます。

取得したら変数bufに格納されます。

ちなみに、Excelファイルの置き場の全てを取得するには、253行目のDir関数を繰り返し実行することで取得することができます。

        '次のファイルを取得する
        buf = Dir()

全てのExcelファイルを取得し終わったら、次のDir関数の戻り値がブランクになるのでDo文のループが終了します。

全てExcelファイル名を取得した後にDir関数を実行した直後の状態

変数bufがブランクなのでDoループから抜ける

注目すべきコード②

次に見て頂きたいのは64行目です。

        'B列のセルにファイル名を出力する
        ws.Range("B" & rowCnt).Value = buf

コードの説明

以上のコードは、Excelファイルの名前をB列のセルに出力する処理のコードです。

今回のサンプルでは、どのExcelファイルにあるモジュール名とプロシージャ名なのかが分かるよう、Excelファイルの名前も出力するようにしています。

注目すべきコード③

次に見て頂きたいのは67行目です。

        'Excelファイルを開き、そのExcelファイルの情報をwbに代入する
        Set wb = Workbooks.Open(filePath & buf)

コードの説明

以上のコードは、Openメソッドの引数にExcelファイルをフルパスで指定して実行し、そのExcelファイルの情報をwbに代入している処理のコードです。

Openメソッドを実行することでExcelファイルが開かれ、マクロがそのExcelファイルのマクロのコードを参照することができます。

つまり、Excelファイルにどんなモジュールがあるのかや、そのモジュール内にどんなプロシージャがあるのかを特定することができるようになります。

注目すべきコード④

次に見て頂きたいのは70行目から84行目です。

        ' 配列を初期化
        ReDim myArray(0)
        
        'VBProjectのVBComponentsコレクション内の各VBComponentに対して以下を繰り返すFor文
        For Each vbcomp In wb.VBProject.VBComponents
        
            '動的配列の再宣言を行う(配列に格納されている値を残したまま)
            ReDim Preserve myArray(aryCnt)
            
            '取得したモジュール名を配列に格納する
            myArray(aryCnt) = vbcomp.Name
            
            'カウンタを1増やす
            aryCnt = aryCnt + 1
            
        Next vbComp

コードの説明

以上のコードは、モジュール名を取得してそのモジュール名を配列に格納する処理のコードです。

コードの詳細

70行目のコードでは、配列myArrayを要素数0で初期化しています。

73行目では、VBProjectのVBComponentsコレクション内の各VBComponentに対して処理を繰り返すFor文を用意し、vbcompにはモジュールが格納されます。

76行目では動的配列の再宣言を行い、79行目ではnameプロパティからモジュールの名称を取得して配列myArrayに格納します。

For文が完了すると、Excelのモジュール名が全て取得されます。

注目すべきコード⑤

次に見て頂きたいのは92行目から95行目です。

            'C列のセルにモジュール名を出力する
            ws.Range("C" & rowCnt).Value = myArray(aryCnt)
            
            'A列のセルに「項番」を出力する
            ws.Range("A" & rowCnt).Value = rowCnt - bgnRowPos + 1

コードの説明

以上のコードは、モジュール名をC列のセルに、項番をA列のセルに出力する処理のコードです。

今回のサンプルでは、モジュール名とプロシージャ名だけではなく項番も出力するようにしています。

注目すべきコード⑥

次に見て頂きたいのは98行目です。

            'VBComponentsプロパティから取得したVBComponentオブジェクトのCodeModuleオブジェクトを取得する
            Set obj = wb.VBProject.VBComponents(myArray(aryCnt)).CodeModule

コードの説明

以上のコードは、VBComponentsプロパティから取得したVBComponentオブジェクトのCodeModuleオブジェクトを取得する処理のコードです。

CodeModuleオブジェクトを取得して変数objに格納していますが、このオブジェクトによりVBAのソースコードを参照することができます。

ソースコード内にあるプロシージャを取得するのにこのオブジェクトが必要になります。

注目すべきコード⑦

次に見て頂きたいのは100行目から105行目です。

            With obj

                '対象モジュールの行数分ループするfor文
                For cnt = 1 To .CountOfLines

                    'プロシージャ名を取得してprocNameに格納する
                    procName = .ProcOfLine(cnt, 0)

コードの説明

以上のコードは、VBAのソースコードの行数分ループさせるループ処理のコードと、プロシージャ名を取得するコードです。

CountOfLinesプロパティはVBAのソースコードの行数のことです。

例えば、VBAのソースコードが10行の場合、CountOfLinesプロパティは10の値を返します。

また、ProcOfLineメソッドはプロシージャ名を取得するメソッドです。

取得したら変数procNameに格納します。

このprocNameの値はシートにプロシージャ名を出力するのに使います。

注目すべきコード⑧

次に見て頂きたいのは108行目です。

                    If .Lines(cnt, 1) <> "" Then
                    
                        '行が空白でない場合

コードの説明

以上のコードは、コードの行が空白でないか判定するために必要な条件文のIFです。

コードの行からプロシージャ名を取得するので、空白行は対象外にします。

注目すべきコード⑨

次に見て頂きたいのは114行目から144行目です。

                        'スコープの取得
                            
                        Select Case True
                                                
                            Case InStr(LCase(.Lines(cnt, 1)), "public ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「public 」が含まれている場合
                                
                                '変数scopeStrに「public」を格納する
                                scopeStr = "public"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "private ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「private 」が含まれている場合
                                
                                '変数scopeStrに「private」を格納する
                                scopeStr = "private"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "friend ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「Friend 」が含まれている場合
                                
                                '変数scopeStrに「friend」を格納する
                                scopeStr = "Friend"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "static ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「Static 」が含まれている場合
                                
                                '変数scopeStrに「static」を格納する
                                scopeStr = "static"
                                                                
                        End Select

コードの説明

以上のコードは、スコープを取得するコードの処理です。

プロシージャに使われているスコープ(public、private、friend、static)がどれかなのかを判定します。

スコープがどれなのかは、行に対してInStr関数を使って判定します。

コードの詳細

116行目のコードでは、InStrの引数に「public 」を指定し、戻り値が0以上の場合はスコープがpublicなので、121行目で変数scopeStrに「public」を格納しています。

ただしpublicの文字列が「Public」のように大文字小文字が混ざっているかもしれないので、LCase関数を使って文字全てを小文字に変換してからInstr関数を実行しています。

なお、変数scopeStrの値は、シートの表のD列に出力するのに使います。

123行目のコードでは、InStrの引数に「private 」を指定し、戻り値が0以上の場合はスコープがprivateなので、128行目で変数scopeStrに「private」を格納しています。

130行目のコードでは、InStrの引数に「friend 」を指定し、戻り値が0以上の場合はスコープがfriendなので、135行目で変数scopeStrに「friend」を格納しています。

137行目のコードでは、InStrの引数に「static 」を指定し、戻り値が0以上の場合はスコープがstaticなので、142行目で変数scopeStrに「static」を格納しています。

注目すべきコード⑩

次に見て頂きたいのは148行目から185行目です。

                        '種類の取得
                        
                        Select Case True
                        
                            Case InStr(LCase(.Lines(cnt, 1)), "sub ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「sub 」が含まれている場合
                                
                                '変数kindStrに「sub」を格納する
                                kindStr = "sub"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "function ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「function 」が含まれている場合
                                
                                '変数kindStrに「function」を格納する
                                kindStr = "function"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "property let ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「property let 」が含まれている場合
                                
                                '変数kindStrに「Property Let」を格納する
                                kindStr = "Property Let"
                                                                
                            Case InStr(LCase(.Lines(cnt, 1)), "property set ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「property set 」が含まれている場合
                                
                                '変数kindStrに「property set」を格納する
                                kindStr = "Property Set"
                                
                            Case InStr(LCase(.Lines(cnt, 1)), "property get ") > 0
                            
                                'プロシージャ名が含まれているソースコードに「property get 」が含まれている場合
                                
                                '変数kindStrに「Property Get」を格納する
                                kindStr = "Property Get"
                                
                        End Select

コードの説明

以上のコードは、プロシージャまたはpropertyの種類を取得するコードの処理です。

プロシージャに使われているプロシージャまたはpropertyの種類(sub、function、property let、Property Set、Property Get)がどれかなのかを判定します。

スコープがどれなのかは、行に対してInStr関数を使って判定します。

コードの詳細

150行目のコードでは、InStrの引数に「sub 」を指定し、戻り値が0以上の場合はプロシージャの種類がsubなので、155行目で変数scopeStrに「sub」を格納しています。

ただしsubの文字列が「Sub」のように大文字小文字が混ざっているかもしれないので、LCase関数を使って文字全てを小文字に変換してからInstr関数を実行しています。

なお、変数kingStrの値は、シートの表のE列に出力するのに使います。

157行目のコードでは、InStrの引数に「function 」を指定し、戻り値が0以上の場合はプロシージャの種類がfunctionなので、162行目で変数scopeStrに「function」を格納しています。

164行目のコードでは、InStrの引数に「property let 」を指定し、戻り値が0以上の場合はpropertyの種類がproperty letなので、169行目で変数scopeStrに「property let」を格納しています。

171行目のコードでは、InStrの引数に「property set 」を指定し、戻り値が0以上の場合はpropertyの種類がproperty setなので、176行目で変数scopeStrに「property set」を格納しています。

178行目のコードでは、InStrの引数に「property get 」を指定し、戻り値が0以上の場合はpropertyの種類がproperty getなので、183行目で変数scopeStrに「property get」を格納しています。

注目すべきコード⑪

次に見て頂きたいのは187行目から197行目です。

                        If scopeStr <> "" Then
                        
                            'scopeStrに値が存在する場合
                        
                            'D列のセルに「スコープ」を出力する
                            ws.Range("D" & rowCnt).Value = scopeStr
                        
                            'scopeStrに空白を設定する
                            scopeStr = ""
                        
                        End If

コードの説明

以上のコードは、scopeStrが空白でない場合に、「注目すべきコード⑨」で取得したスコープをD列のセルに出力するコードです。

スコープが取得されてscopeStrに値が格納されていれば、スコープをD列のセルに出力します。

コードの詳細

187行目のコードでは、scopeStrに値(スコープ)が格納されているか判定します。

もしscopeStrに値(スコープ)が格納されている場合は、192行目でD列のセルにscopeStrの値(スコープ)を出力します。

195行目のコードでは、scopeStrに空白を設定しています。

次に見つけたプロシージャにスコープが無い場合にscopeStrの値(スコープ)が入ったままだと、そのままスコープがD列のセルに出力されてしまうので空白を設定しておきます。

注目すべきコード⑫

次に見て頂きたいのは199行目から224行目です。

                        If kindStr <> "" Then
                        
                            'kindStrに値が存在する場合
                        
                            'E列のセルに「種類」を出力する
                            ws.Range("E" & rowCnt).Value = kindStr
                            
                            'F列のセルにプロシージャ名を出力する
                            ws.Range("F" & rowCnt).Value = procName
                            
                            'A列のセルに「項番」を出力する
                            ws.Range("A" & rowCnt).Value = rowCnt - bgnRowPos + 1
                                                        
                            'kindStrを空白に設定する
                            kindStr = ""
                            
                            'procNameを空白に設定する
                            procName = ""
                            
                            'rowCntの値を1つ増やす
                            rowCnt = rowCnt + 1
                            
                            'procNumの値を1つ増やす
                            procNum = procNum + 1
                        
                        End If

以上のコードは、kindStrが空白でない場合に、「注目すべきコード⑩」で取得したプロシージャの種類をE列に、プロシージャ名をF列に、さらに項番をA列のセルに出力するコードです。

また、kindStrとprocNameを空白に、rowCntとprocNumの値を1つ増やしています。

コードの詳細

199行目のコードでは、kindStrに値(プロシージャの種類)が格納されているか判定します。

もしkindStrに値(プロシージャの種類)が格納されている場合は、204行目でE列のセルにkindStrの値(プロシージャの種類)を出力します。

207行目のコードでは、F列のセルにプロシージャ名を出力します。

210行目のコードでは、A列のセルに項番を出力します。

213行目のコードではkindStrに空白を、216行目のコードではprocNameに空白を設定しています。

219行目のコードではrowCntに1を、22行目のコードではではprocNumに1を増やしています。

注目すべきコード⑬

次に見て頂きたいのは234行目から241行目です。

            If procNum = 0 Then

                'プロシージャが無い場合

                'rowCntの値を1つ増やす
                rowCnt = rowCnt + 1
                
            End If

コードの説明

以上のコードは、モジュール内のプロシージャが0件かどうかを判定し、0件の場合はrowCntの値を1つ増やす処理のコードです。

モジュール内のプロシージャが0件の場合に、次に探すモジュールの表の出力先が1行下になるのでここでrowCntの値を1つ増やしておきます。

注目すべきコード⑭

次に見て頂きたいのは248行目から251行目です。

        'obj変数にNothingを代入してメモリを解放する
        Set obj = Nothing

        '開いたExcelファイルを閉じる
        Workbooks(buf).Close SaveChanges:=False

コードの説明

以上のコードは、obj変数にNothingを代入してメモリを解放し、開いているExcelファイルを閉じる処理のコードです。

以上のコードまでで、1つのExcelファイル内のモジュール名とプロシージャ名が全て取得し終わったので、メモリを解放と開いているExcelファイルを閉じる処理を行います。

なお、Excelファイルはあくまでモジュール名とプロシージャ名を取得するためだけに開いたので、Excelファイルを閉じる場合は何も変更しないでおきたいです。

Excelファイルに何も変更しないで閉じる場合は、251行のコードのようにcloseメソッドの引数SaveChangesにFalseを指定して実行します。

これでExcelファイルは何も変更されずに閉じることができます。

動作確認

マクロ実行前

今回は以下のファイルを用意しました。

Excelファイルの格納先をA2の黄色のセルに入力しています。

Excelファイルの格納先は下の画像の通りです。

マクロ実行後

実行ボタンをクリックしてマクロを実行すると、フォルダ内のExcelにあるモジュール名とプロシージャ名を全て取得されています。

最後に

この記事では、フォルダ内のExcelにあるモジュール名とプロシージャ名を全て取得する方法についてご説明しました。

Excelにあるモジュール名とプロシージャ名を確認するのには、VBEをわざわざ開かないといけません。

Excelファイルを開いてVBE上で確認するのが面倒だと感じている場合に、今回紹介したマクロを使えば、お手軽にExcelにあるモジュール名とプロシージャ名が確認できるので参考にしてみてくださいね。

プログラミングのスキルを習得するなら

プログラミングのスキルを習得したい、今のスキルをもっと高めたい、そう考えているなら「プログラミングスクール」がおすすめです。

プログラミングのスキルの基礎を身につけるなら「TechAcademy」で1週間の無料体験があるので、これで「プログラミングの基礎」を学ぶのにおすすめですよ。

→ TechAcademyの「1週間 無料体験」はこちら