【ExcelVBA】ExcelのマクロからMySQLのテーブルにデータを追加するには

この記事では、ExcelのマクロからMySQLのテーブルにデータを追加する方法についてご説明します。

Table of Contents

【動画】ExcelのマクロからMySQLのテーブルにデータを追加する実際の動き

本題に入る前に、まずは次の動画をご覧ください。

Connectionインスタンスの生成してMySQLのデータベースへの接続情報を用意したらConnectionインスタンスのConnectionStringプロパティに代入し、Openメソッドを実行することで、マクロがMySQLのデータベースに接続しています。

マクロがMySQLのデータベースに接続したらSQLのINSERT文を実行し、Excelのセルに入力されたデータをMySQLのテーブルに追加しています。

目次へ戻る

マクロ作成の流れ

STEP.1

Connectionインスタンスを生成する

Connectionインスタンスを生成します。

STEP.2

MySQLへの接続情報を取得する

MySQLへの接続情報を取得します。

STEP.3

STEP.2の接続情報をOpenメソッドの引数に指定してOpenメソッドを実行する

STEP.2の接続情報をOpenメソッドの引数に指定してOpenメソッドを実行します。
実行すると、ExcelのマクロがMySQLのデータベースに接続されます。

STEP.4

SQLのINSERT文を実行する

SQLのINSERT文を実行します。
正常に処理が実行されると、MySQLのテーブルにデータが追加されます。

目次へ戻る

ExcelファイルとMySQLのテーブルデータの例

今回は次のExcelファイルを用意しました。

また、MySQLのテーブルデータは次の通りです。

テーブルにデータが10件存在しています。

今回はこのテーブルに、Excelのセルに入力されたデータをマクロが追加します。

追加された結果は下の画面の通りです。

目次へ戻る

コードの例

Option Explicit

Private Sub btn_exec_Click()

    Dim cn          As ADODB.Connection     'Connection用変数
    Dim sqlStr      As String               'SQL用変数
    Dim ws          As Worksheet
    
    'シートを取得する
    Set ws = Worksheets("work")
        
    'Connectionインスタンスの生成
    Set cn = New ADODB.Connection
    
    'MySQLへの接続情報の取得
    cn.ConnectionString = "Driver={MySQL ODBC 8.1 ANSI Driver};" & _
                          "Server=localhost;" & _
                          "Port=3306;" & _
                          "Database=testdb;" & _
                          "User=root;" & _
                          "Password=testPass@123456"
                          
    'コネクションを開く
    cn.Open
        
    'INSERT文を用意する(syainテーブルにデータを追加)
    sqlStr = "INSERT INTO"
    sqlStr = sqlStr & " syain"
    sqlStr = sqlStr & " (id, name, address, age)"
    sqlStr = sqlStr & " VALUES"
    sqlStr = sqlStr & " ("
    sqlStr = sqlStr & CLng(ws.Range("valID").Value)
    sqlStr = sqlStr & ", '" & ws.Range("valName").Value & "'"
    sqlStr = sqlStr & ", '" & ws.Range("valAddress").Value & "'"
    sqlStr = sqlStr & ", " & CLng(ws.Range("valAge").Value)
    sqlStr = sqlStr & ")"
    
    'INSERT文を実行する
    cn.Execute sqlStr
    
    '後処理
    cn.Close
        
End Sub

注目すべきコード①

最初に見て頂きたいのは13行目です。

    'Connectionインスタンスの生成
    Set cn = New ADODB.Connection

コードの説明

以上のコードは、マクロがMySQLのデータベースに接続するための接続情報を取得して接続するコードです。

このインスタンスがないとマクロがMySQLのデータベースに接続することができないので必ず生成しておきます。

注目すべきコード②

次に見て頂きたいのは16行目から21行目です。

    'MySQLへの接続情報の取得
    cn.ConnectionString = "Driver={MySQL ODBC 8.1 ANSI Driver};" & _
                          "Server=localhost;" & _
                          "Port=3306;" & _
                          "Database=testdb;" & _
                          "User=root;" & _
                          "Password=testPass@123456"

コードの説明

以上のコードは、マクロがMySQLのデータベースに接続するための接続情報を用意するコードです。

MySQLのデータベースに接続するための接続情報はいくつかの引数が必要になります。

Driver

Driverには、マクロがMySQLのデータベースに接続するのに必要なODBCドライバーの情報を指定します。

Server

Serverには、接続したいMySQLのサーバの名称を指定します。

今回はlocalhostに接続します。

【参考：MySQL Workbenchの画面】

Port

Portには、ポートの値を指定します。

【参考：MySQL Workbenchの画面】

Database

Databaseには、接続したいデータベース名を指定します。

【参考：MySQL Workbenchの画面】

User

Userには、MySQLのデータベースに接続するためのユーザ名を指定します。

【参考：MySQL Workbenchの画面】

Password

Passwordには、MySQLのデータベースに接続するためのパスワードを指定します。

注目すべきコード③

次に見て頂きたいのは24行目です。

    'コネクションを開く
    cn.Open

コードの説明

以上のコードは、ConnectionインスタンスのOpenメソッドを実行して、マクロがMySQLのデータベースに接続する処理のコードです。

Connectionインスタンスには「注目すべきコード②」で説明した通り、マクロがMySQLのデータベースに接続するための接続情報をConnectionStringプロパティに代入しているので、ここではOpenメソッドを実行することでマクロがMySQLのデータベースに接続されます。

注目すべきコード④

次に見て頂きたいのは27行目から36行目です。

    'INSERT文を用意する(syainテーブルにデータを追加)
    sqlStr = "INSERT INTO"
    sqlStr = sqlStr & " syain"
    sqlStr = sqlStr & " (id, name, address, age)"
    sqlStr = sqlStr & " VALUES"
    sqlStr = sqlStr & " ("
    sqlStr = sqlStr & CLng(ws.Range("valID").Value)
    sqlStr = sqlStr & ", '" & ws.Range("valName").Value & "'"
    sqlStr = sqlStr & ", '" & ws.Range("valAddress").Value & "'"
    sqlStr = sqlStr & ", " & CLng(ws.Range("valAge").Value)
    sqlStr = sqlStr & ")"

コードの説明

以上のコードは、Excelのセルに入力されたデータをMySQLのテーブルに追加するInsert文を組み立てているコードです。

4つの値(項番(id)、名前(name)、住所(address)、年齢(age))を1レコードとしてsyainテーブルに追加します。

4つの値は32行目から35行目で指定しています。

以上のコードだけではINSERT文が分かりにくいと思うので、実際に実行するINSERT文をサンプルで以下にお見せします。

INSERT文(サンプルのExcelのシートに入力された値を追加する)

INSERT INTO syain(
      id
    , name
    , address
    , age
)
VALUES(
      11
    , '吉田 大地'
    , '埼玉県熊谷市'
    , 35
)

注目すべきコード⑤

次に見て頂きたいのは39行目です。

    'INSERT文を実行する
    cn.Execute sqlStr

コードの説明

以上のコードは、INSERT文をマクロがMySQL側で実行するよう要求し実行する処理のコードです。

ConnectionインスタンスのExecuteメソッドにINSERT文を引数に指定し実行することでMySQL側でINSERT文が実行されます。

目次へ戻る

動作確認

「ExcelファイルとMySQLのテーブルデータの例」をご覧ください。

目次へ戻る

【注意】参照設定が必要です

一つ注意点があるのですが、先ほどのコードを動かすには参照設定が必要です。

参照設定の一覧(下の画像を参考)から次の項目(ライブラリ)にチェックを付けて「OK」ボタンをクリックします。

Microsoft ActiveX Data Objects 2.8 Library(msado28.tlb)

なぜ必要かというと、Excelのマクロのコードの5行目の「ADODB.Connection」と6行目の「ADODB.Recordset」というオブジェクトが「msado28.tlb」というファイルを参照するからです。

    Dim cn          As ADODB.Connection     'Connection用変数

この参照設定をしないと下の画像のエラーが出ますので必ず行う必要があります。

ここでは「msado28.tlb」とは何者かについては記事の本題から逸れてしまうので詳細は割愛しますが、マクロで「ADODB.Connection」「ADODB.Recordset」というオブジェクトを使う場合は参照設定しないと動かない、程度に思って頂ければと思います。

目次へ戻る

最後に

この記事では、ExcelのマクロからMySQLのテーブルにデータを追加する方法についてご説明しました。

ExcelのマクロからMySQLのテーブルにデータを追加したいときは本記事を参考にしてみてくださいね。

プログラミングのスキルを習得するなら

プログラミングのスキルを習得したい、今のスキルをもっと高めたい、そう考えているなら「プログラミングスクール」がおすすめです。

プログラミングのスキルの基礎を身につけるなら「TechAcademy」で1週間の無料体験があるので、これで「プログラミングの基礎」を学ぶのにおすすめですよ。

→　TechAcademyの「1週間無料体験」はこちら

目次へ戻る